Gecko [ edgpens.lpkmn.gov.my ]

Name	Size	Permission
README.txt	1.65 KB	-rw-rw-rw-
aap.vim	265 B	-rw-rw-rw-
ada.vim	11.06 KB	-rw-rw-rw-
ant.vim	290 B	-rw-rw-rw-
automake.vim	243 B	-rw-rw-rw-
awk.vim	7.68 KB	-rw-rw-rw-
bash.vim	350 B	-rw-rw-rw-
basic.vim	250 B	-rw-rw-rw-
bib.vim	346 B	-rw-rw-rw-
bst.vim	1.86 KB	-rw-rw-rw-
bzl.vim	2.86 KB	-rw-rw-rw-
c.vim	325 B	-rw-rw-rw-
cdl.vim	4.26 KB	-rw-rw-rw-
ch.vim	470 B	-rw-rw-rw-
chaiscript.vim	1.18 KB	-rw-rw-rw-
changelog.vim	264 B	-rw-rw-rw-
clojure.vim	11.29 KB	-rw-rw-rw-
cmake.vim	2.66 KB	-rw-rw-rw-
cobol.vim	8.63 KB	-rw-rw-rw-
config.vim	2.17 KB	-rw-rw-rw-
confini.vim	196 B	-rw-rw-rw-
context.vim	752 B	-rw-rw-rw-
cpp.vim	329 B	-rw-rw-rw-
cs.vim	1.88 KB	-rw-rw-rw-
css.vim	1.77 KB	-rw-rw-rw-
cucumber.vim	2.62 KB	-rw-rw-rw-
cuda.vim	305 B	-rw-rw-rw-
d.vim	605 B	-rw-rw-rw-
dictconf.vim	411 B	-rw-rw-rw-
dictdconf.vim	414 B	-rw-rw-rw-
docbk.vim	336 B	-rw-rw-rw-
dosbatch.vim	1.35 KB	-rw-rw-rw-
dtd.vim	11.79 KB	-rw-rw-rw-
dtrace.vim	451 B	-rw-rw-rw-
dune.vim	332 B	-rw-rw-rw-
dylan.vim	2.75 KB	-rw-rw-rw-
eiffel.vim	3.24 KB	-rw-rw-rw-
elm.vim	3.2 KB	-rw-rw-rw-
erlang.vim	48.89 KB	-rw-rw-rw-
eruby.vim	2.95 KB	-rw-rw-rw-
eterm.vim	743 B	-rw-rw-rw-
falcon.vim	13.84 KB	-rw-rw-rw-
fennel.vim	273 B	-rw-rw-rw-
fortran.vim	7.54 KB	-rw-rw-rw-
framescript.vim	891 B	-rw-rw-rw-
freebasic.vim	237 B	-rw-rw-rw-
gitconfig.vim	841 B	-rw-rw-rw-
gitolite.vim	1.29 KB	-rw-rw-rw-
go.vim	1.63 KB	-rw-rw-rw-
haml.vim	2.19 KB	-rw-rw-rw-
hamster.vim	1.65 KB	-rw-rw-rw-
hog.vim	1.85 KB	-rw-rw-rw-
html.vim	33.11 KB	-rw-rw-rw-
htmldjango.vim	273 B	-rw-rw-rw-
idlang.vim	1.68 KB	-rw-rw-rw-
ishd.vim	1.83 KB	-rw-rw-rw-
j.vim	1.77 KB	-rw-rw-rw-
java.vim	4.19 KB	-rw-rw-rw-
javascript.vim	15 KB	-rw-rw-rw-
javascriptreact.vim	109 B	-rw-rw-rw-
json.vim	4.42 KB	-rw-rw-rw-
jsonc.vim	4.62 KB	-rw-rw-rw-
jsp.vim	462 B	-rw-rw-rw-
julia.vim	15.2 KB	-rw-rw-rw-
krl.vim	4.26 KB	-rw-rw-rw-
ld.vim	1.82 KB	-rw-rw-rw-
less.vim	243 B	-rw-rw-rw-
lifelines.vim	638 B	-rw-rw-rw-
liquid.vim	2.03 KB	-rw-rw-rw-
lisp.vim	353 B	-rw-rw-rw-
logtalk.vim	1.82 KB	-rw-rw-rw-
lua.vim	1.88 KB	-rw-rw-rw-
mail.vim	355 B	-rw-rw-rw-
make.vim	3.48 KB	-rw-rw-rw-
matlab.vim	4.81 KB	-rw-rw-rw-
meson.vim	5.19 KB	-rw-rw-rw-
mf.vim	156 B	-rw-rw-rw-
mma.vim	2.31 KB	-rw-rw-rw-
mp.vim	11.06 KB	-rw-rw-rw-
nginx.vim	407 B	-rw-rw-rw-
nsis.vim	3.23 KB	-rw-rw-rw-
objc.vim	1.65 KB	-rw-rw-rw-
ocaml.vim	8.98 KB	-rw-rw-rw-
occam.vim	4.63 KB	-rw-rw-rw-
pascal.vim	5.66 KB	-rw-rw-rw-
perl.vim	5.85 KB	-rw-rw-rw-
php.vim	25.29 KB	-rw-rw-rw-
postscr.vim	1.64 KB	-rw-rw-rw-
pov.vim	2.71 KB	-rw-rw-rw-
prolog.vim	1.91 KB	-rw-rw-rw-
ps1.vim	410 B	-rw-rw-rw-
pyrex.vim	326 B	-rw-rw-rw-
python.vim	6.82 KB	-rw-rw-rw-
qb64.vim	232 B	-rw-rw-rw-
r.vim	13.71 KB	-rw-rw-rw-
raku.vim	3.34 KB	-rw-rw-rw-
raml.vim	285 B	-rw-rw-rw-
readline.vim	786 B	-rw-rw-rw-
rhelp.vim	2.77 KB	-rw-rw-rw-
rmd.vim	2.14 KB	-rw-rw-rw-
rnoweb.vim	1.06 KB	-rw-rw-rw-
rpl.vim	1.82 KB	-rw-rw-rw-
rrst.vim	1.17 KB	-rw-rw-rw-
rst.vim	1.78 KB	-rw-rw-rw-
ruby.vim	30.32 KB	-rw-rw-rw-
rust.vim	6.35 KB	-rw-rw-rw-
sas.vim	5.18 KB	-rw-rw-rw-
sass.vim	994 B	-rw-rw-rw-
scala.vim	19.2 KB	-rw-rw-rw-
scheme.vim	372 B	-rw-rw-rw-
scss.vim	191 B	-rw-rw-rw-
sdl.vim	2.76 KB	-rw-rw-rw-
sh.vim	9.04 KB	-rw-rw-rw-
sml.vim	6.42 KB	-rw-rw-rw-
sql.vim	1.18 KB	-rw-rw-rw-
sqlanywhere.vim	12.96 KB	-rw-rw-rw-
sshconfig.vim	796 B	-rw-rw-rw-
systemd.vim	205 B	-rw-rw-rw-
systemverilog.vim	8.51 KB	-rw-rw-rw-
tcl.vim	2.48 KB	-rw-rw-rw-
tcsh.vim	1.35 KB	-rw-rw-rw-
teraterm.vim	1.38 KB	-rw-rw-rw-
tex.vim	13.37 KB	-rw-rw-rw-
tf.vim	1.57 KB	-rw-rw-rw-
tilde.vim	1.11 KB	-rw-rw-rw-
treetop.vim	785 B	-rw-rw-rw-
typescript.vim	14.14 KB	-rw-rw-rw-
vb.vim	2.04 KB	-rw-rw-rw-
verilog.vim	7.98 KB	-rw-rw-rw-
vhdl.vim	14.32 KB	-rw-rw-rw-
vim.vim	5.91 KB	-rw-rw-rw-
vroom.vim	379 B	-rw-rw-rw-
wast.vim	458 B	-rw-rw-rw-
xf86conf.vim	786 B	-rw-rw-rw-
xhtml.vim	269 B	-rw-rw-rw-
xinetd.vim	1.28 KB	-rw-rw-rw-
xml.vim	7.6 KB	-rw-rw-rw-
xsd.vim	253 B	-rw-rw-rw-
xslt.vim	297 B	-rw-rw-rw-
yacc.vim	858 B	-rw-rw-rw-
yaml.vim	5.35 KB	-rw-rw-rw-
zimbu.vim	3.85 KB	-rw-rw-rw-
zsh.vim	411 B	-rw-rw-rw-

Code Editor : javascript.vim

" Vim indent file
" Language: Javascript
" Maintainer: Chris Paul ( https://github.com/bounceme )
" URL: https://github.com/pangloss/vim-javascript
" Last Change: December 4, 2017

" Only load this indent file when no other was loaded.
if exists('b:did_indent')
  finish
endif
let b:did_indent = 1

" Now, set up our indentation expression and keys that trigger it.
setlocal indentexpr=GetJavascriptIndent()
setlocal autoindent nolisp nosmartindent
setlocal indentkeys+=0],0)
" Testable with something like:
" vim  -eNs "+filetype plugin indent on" "+syntax on" "+set ft=javascript" \
"       "+norm! gg=G" '+%print' '+:q!' testfile.js \
"       | diff -uBZ testfile.js -

let b:undo_indent = 'setlocal indentexpr< smartindent< autoindent< indentkeys<'

" Only define the function once.
if exists('*GetJavascriptIndent')
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

" indent correctly if inside <script>
" vim/vim@690afe1 for the switch from cindent
" overridden with b:html_indent_script1
call extend(g:,{'html_indent_script1': 'inc'},'keep')

" Regex of syntax group names that are or delimit string or are comments.
let s:bvars = {
      \ 'syng_strcom': 'string\|comment\|regex\|special\|doc\|template\%(braces\)\@!',
      \ 'syng_str': 'string\|template\|special' }
" template strings may want to be excluded when editing graphql:
" au! Filetype javascript let b:syng_str = '^\%(.*template\)\@!.*string\|special'
" au! Filetype javascript let b:syng_strcom = '^\%(.*template\)\@!.*string\|comment\|regex\|special\|doc'

function s:GetVars()
  call extend(b:,extend(s:bvars,{'js_cache': [0,0,0]}),'keep')
endfunction

" Get shiftwidth value
if exists('*shiftwidth')
  function s:sw()
    return shiftwidth()
  endfunction
else
  function s:sw()
    return &l:shiftwidth ? &l:shiftwidth : &l:tabstop
  endfunction
endif

" Performance for forwards search(): start search at pos rather than masking
" matches before pos.
let s:z = has('patch-7.4.984') ? 'z' : ''

" Expression used to check whether we should skip a match with searchpair().
let s:skip_expr = "s:SynAt(line('.'),col('.')) =~? b:syng_strcom"
let s:in_comm = s:skip_expr[:-14] . "'comment\\|doc'"

let s:rel = has('reltime')
" searchpair() wrapper
if s:rel
  function s:GetPair(start,end,flags,skip)
    return searchpair('\m'.a:start,'','\m'.a:end,a:flags,a:skip,s:l1,a:skip ==# 's:SkipFunc()' ? 2000 : 200)
  endfunction
else
  function s:GetPair(start,end,flags,skip)
    return searchpair('\m'.a:start,'','\m'.a:end,a:flags,a:skip,s:l1)
  endfunction
endif

function s:SynAt(l,c)
  let byte = line2byte(a:l) + a:c - 1
  let pos = index(s:synid_cache[0], byte)
  if pos == -1
    let s:synid_cache[:] += [[byte], [synIDattr(synID(a:l, a:c, 0), 'name')]]
  endif
  return s:synid_cache[1][pos]
endfunction

function s:ParseCino(f)
  let [divider, n, cstr] = [0] + matchlist(&cino,
        \ '\%(.*,\)\=\%(\%d'.char2nr(a:f).'$-$\=$[.s0-9]*$\)\=')[1:2]
  for c in split(cstr,'\zs')
    if c == '.' && !divider
      let divider = 1
    elseif c ==# 's'
      if n !~ '\d'
        return n . s:sw() + 0
      endif
      let n = str2nr(n) * s:sw()
      break
    else
      let [n, divider] .= [c, 0]
    endif
  endfor
  return str2nr(n) / max([str2nr(divider),1])
endfunction

" Optimized {skip} expr, only callable from the search loop which
" GetJavascriptIndent does to find the containing [[{(] (side-effects)
function s:SkipFunc()
  if s:top_col == 1
    throw 'out of bounds'
  elseif s:check_in
    if eval(s:skip_expr)
      return 1
    endif
    let s:check_in = 0
  elseif getline('.') =~ '\%<'.col('.').'c\/.\{-}\/\|\%>'.col('.').'c[''"]\|\\$'
    if eval(s:skip_expr)
      return 1
    endif
  elseif search('\m`\|\${\|\*\/','nW'.s:z,s:looksyn)
    if eval(s:skip_expr)
      let s:check_in = 1
      return 1
    endif
  else
    let s:synid_cache[:] += [[line2byte('.') + col('.') - 1], ['']]
  endif
  let [s:looksyn, s:top_col] = getpos('.')[1:2]
endfunction

function s:AlternatePair()
  let [pat, l:for] = ['[][(){};]', 2]
  while s:SearchLoop(pat,'bW','s:SkipFunc()')
    if s:LookingAt() == ';'
      if !l:for
        if s:GetPair('{','}','bW','s:SkipFunc()')
          return
        endif
        break
      else
        let [pat, l:for] = ['[{}();]', l:for - 1]
      endif
    else
      let idx = stridx('])}',s:LookingAt())
      if idx == -1
        return
      elseif !s:GetPair(['\[','(','{'][idx],'])}'[idx],'bW','s:SkipFunc()')
        break
      endif
    endif
  endwhile
  throw 'out of bounds'
endfunction

function s:Nat(int)
  return a:int * (a:int > 0)
endfunction

function s:LookingAt()
  return getline('.')[col('.')-1]
endfunction

function s:Token()
  return s:LookingAt() =~ '\k' ? expand('<cword>') : s:LookingAt()
endfunction

function s:PreviousToken(...)
  let [l:pos, tok] = [getpos('.'), '']
  if search('\m\k\{1,}\|\S','ebW')
    if getline('.')[col('.')-2:col('.')-1] == '*/'
      if eval(s:in_comm) && !s:SearchLoop('\S\ze\_s*\/[/*]','bW',s:in_comm)
        call setpos('.',l:pos)
      else
        let tok = s:Token()
      endif
    else
      let two = a:0 || line('.') != l:pos[1] ? strridx(getline('.')[:col('.')],'//') + 1 : 0
      if two && eval(s:in_comm)
        call cursor(0,two)
        let tok = s:PreviousToken(1)
        if tok is ''
          call setpos('.',l:pos)
        endif
      else
        let tok = s:Token()
      endif
    endif
  endif
  return tok
endfunction

function s:Pure(f,...)
  return eval("[call(a:f,a:000),cursor(a:firstline,".col('.').")][0]")
endfunction

function s:SearchLoop(pat,flags,expr)
  return s:GetPair(a:pat,'\_$.',a:flags,a:expr)
endfunction

function s:ExprCol()
  if getline('.')[col('.')-2] == ':'
    return 1
  endif
  let bal = 0
  while s:SearchLoop('[{}?:]','bW',s:skip_expr)
    if s:LookingAt() == ':'
      if getline('.')[col('.')-2] == ':'
        call cursor(0,col('.')-1)
        continue
      endif
      let bal -= 1
    elseif s:LookingAt() == '?'
      if getline('.')[col('.'):col('.')+1] =~ '^\.\d\@!'
        continue
      elseif !bal
        return 1
      endif
      let bal += 1
    elseif s:LookingAt() == '{'
      return !s:IsBlock()
    elseif !s:GetPair('{','}','bW',s:skip_expr)
      break
    endif
  endwhile
endfunction

" configurable regexes that define continuation lines, not including (, {, or [.
let s:opfirst = '^' . get(g:,'javascript_opfirst',
      \ '\C\%([<>=,.?^%|/&]\|$[-:+]$\1\@!\|\*\+\|!=\|in\%(stanceof\)\=\>\)')
let s:continuation = get(g:,'javascript_continuation',
      \ '\C\%([<=,.~!?/*^%|&:]\|+\@<!+\|-\@<!-\|=\@<!>\|\<\%(typeof\|new\|delete\|void\|in\|instanceof\|await\)\)') . '$'

function s:Continues()
  let tok = matchstr(strpart(getline('.'),col('.')-15,15),s:continuation)
  if tok =~ '[a-z:]'
    return tok == ':' ? s:ExprCol() : s:PreviousToken() != '.'
  elseif tok !~ '[/>]'
    return tok isnot ''
  endif
  return s:SynAt(line('.'),col('.')) !~? (tok == '>' ? 'jsflow\|^html' : 'regex')
endfunction

" Check if line 'lnum' has a balanced amount of parentheses.
function s:Balanced(lnum,line)
  let l:open = 0
  let pos = match(a:line, '[][(){}]')
  while pos != -1
    if s:SynAt(a:lnum,pos + 1) !~? b:syng_strcom
      let l:open += match(' ' . a:line[pos],'[[({]')
      if l:open < 0
        return
      endif
    endif
    let pos = match(a:line, !l:open ? '[][(){}]' : '()' =~ a:line[pos] ?
          \ '[()]' : '{}' =~ a:line[pos] ? '[{}]' : '[][]', pos + 1)
  endwhile
  return !l:open
endfunction

function s:OneScope()
  if s:LookingAt() == ')' && s:GetPair('(', ')', 'bW', s:skip_expr)
    let tok = s:PreviousToken()
    return (count(split('for if let while with'),tok) ||
          \ tok =~# '^await$\|^each$' && s:PreviousToken() ==# 'for') &&
          \ s:Pure('s:PreviousToken') != '.' && !(tok == 'while' && s:DoWhile())
  elseif s:Token() =~# '^else$\|^do$'
    return s:Pure('s:PreviousToken') != '.'
  elseif strpart(getline('.'),col('.')-2,2) == '=>'
    call cursor(0,col('.')-1)
    if s:PreviousToken() == ')'
      return s:GetPair('(', ')', 'bW', s:skip_expr)
    endif
    return 1
  endif
endfunction

function s:DoWhile()
  let cpos = searchpos('\m\<','cbW')
  while s:SearchLoop('\C[{}]\|\<\%(do\|while\)\>','bW',s:skip_expr)
    if s:LookingAt() =~ '\a'
      if s:Pure('s:IsBlock')
        if s:LookingAt() ==# 'd'
          return 1
        endif
        break
      endif
    elseif s:LookingAt() != '}' || !s:GetPair('{','}','bW',s:skip_expr)
      break
    endif
  endwhile
  call call('cursor',cpos)
endfunction

" returns total offset from braceless contexts. 'num' is the lineNr which
" encloses the entire context, 'cont' if whether a:firstline is a continued
" expression, which could have started in a braceless context
function s:IsContOne(cont)
  let [l:num, b_l] = [b:js_cache[1] + !b:js_cache[1], 0]
  let pind = b:js_cache[1] ? indent(b:js_cache[1]) + s:sw() : 0
  let ind = indent('.') + !a:cont
  while line('.') > l:num && ind > pind || line('.') == l:num
    if indent('.') < ind && s:OneScope()
      let b_l += 1
    elseif !a:cont || b_l || ind < indent(a:firstline)
      break
    else
      call cursor(0,1)
    endif
    let ind = min([ind, indent('.')])
    if s:PreviousToken() is ''
      break
    endif
  endwhile
  return b_l
endfunction

function s:IsSwitch()
  call call('cursor',b:js_cache[1:])
  return search('\m\C\%#.\_s*\%(\%(\/\/.*\_$\|\/\*\_.\{-}\*\/\)\@>\_s*\)*\%(case\|default\)\>','nWc'.s:z)
endfunction

" https://github.com/sweet-js/sweet.js/wiki/design#give-lookbehind-to-the-reader
function s:IsBlock()
  let tok = s:PreviousToken()
  if join(s:stack) =~? 'xml\|jsx' && s:SynAt(line('.'),col('.')-1) =~? 'xml\|jsx'
    let s:in_jsx = 1
    return tok != '{'
  elseif tok =~ '\k'
    if tok ==# 'type'
      return s:Pure('eval',"s:PreviousToken() !~# '^\\%(im\\|ex\\)port$' || s:PreviousToken() == '.'")
    elseif tok ==# 'of'
      return s:Pure('eval',"!s:GetPair('[[({]','[])}]','bW',s:skip_expr) || s:LookingAt() != '(' ||"
            \ ."s:{s:PreviousToken() ==# 'await' ? 'Previous' : ''}Token() !=# 'for' || s:PreviousToken() == '.'")
    endif
    return index(split('return const let import export extends yield default delete var await void typeof throw case new in instanceof')
          \ ,tok) < (line('.') != a:firstline) || s:Pure('s:PreviousToken') == '.'
  elseif tok == '>'
    return getline('.')[col('.')-2] == '=' || s:SynAt(line('.'),col('.')) =~? 'jsflow\|^html'
  elseif tok == '*'
    return s:Pure('s:PreviousToken') == ':'
  elseif tok == ':'
    return s:Pure('eval',"s:PreviousToken() =~ '^\\K\\k*$' && !s:ExprCol()")
  elseif tok == '/'
    return s:SynAt(line('.'),col('.')) =~? 'regex'
  elseif tok !~ '[=~!<,.?^%|&([]'
    return tok !~ '[-+]' || line('.') != a:firstline && getline('.')[col('.')-2] == tok
  endif
endfunction

function GetJavascriptIndent()
  call s:GetVars()
  let s:synid_cache = [[],[]]
  let l:line = getline(v:lnum)
  " use synstack as it validates syn state and works in an empty line
  let s:stack = [''] + map(synstack(v:lnum,1),"synIDattr(v:val,'name')")

" start with strings,comments,etc.
  if s:stack[-1] =~? 'comment\|doc'
    if l:line =~ '^\s*\*'
      return cindent(v:lnum)
    elseif l:line !~ '^\s*\/[/*]'
      return -1
    endif
  elseif s:stack[-1] =~? b:syng_str
    if b:js_cache[0] == v:lnum - 1 && s:Balanced(v:lnum-1,getline(v:lnum-1))
      let b:js_cache[0] = v:lnum
    endif
    return -1
  endif

let s:l1 = max([0,prevnonblank(v:lnum) - (s:rel ? 2000 : 1000),
        \ get(get(b:,'hi_indent',{}),'blocklnr')])
  call cursor(v:lnum,1)
  if s:PreviousToken() is ''
    return
  endif
  let [l:lnum, pline] = [line('.'), getline('.')[:col('.')-1]]

let l:line = substitute(l:line,'^\s*','','')
  let l:line_raw = l:line
  if l:line[:1] == '/*'
    let l:line = substitute(l:line,'^\%(\/\*.\{-}\*\/\s*\)*','','')
  endif
  if l:line =~ '^\/[/*]'
    let l:line = ''
  endif

" the containing paren, bracket, or curly. Many hacks for performance
  call cursor(v:lnum,1)
  let idx = index([']',')','}'],l:line[0])
  if b:js_cache[0] > l:lnum && b:js_cache[0] < v:lnum ||
        \ b:js_cache[0] == l:lnum && s:Balanced(l:lnum,pline)
    call call('cursor',b:js_cache[1:])
  else
    let [s:looksyn, s:top_col, s:check_in, s:l1] = [v:lnum - 1,0,0,
          \ max([s:l1, &smc ? search('\m^.\{'.&smc.',}','nbW',s:l1 + 1) + 1 : 0])]
    try
      if idx != -1
        call s:GetPair(['\[','(','{'][idx],'])}'[idx],'bW','s:SkipFunc()')
      elseif getline(v:lnum) !~ '^\S' && s:stack[-1] =~? 'block\|^jsobject$'
        call s:GetPair('{','}','bW','s:SkipFunc()')
      else
        call s:AlternatePair()
      endif
    catch /^\Cout of bounds$/
      call cursor(v:lnum,1)
    endtry
    let b:js_cache[1:] = line('.') == v:lnum ? [0,0] : getpos('.')[1:2]
  endif

let [b:js_cache[0], num] = [v:lnum, b:js_cache[1]]

let [num_ind, is_op, b_l, l:switch_offset, s:in_jsx] = [s:Nat(indent(num)),0,0,0,0]
  if !num || s:LookingAt() == '{' && s:IsBlock()
    let ilnum = line('.')
    if num && !s:in_jsx && s:LookingAt() == ')' && s:GetPair('(',')','bW',s:skip_expr)
      if ilnum == num
        let [num, num_ind] = [line('.'), indent('.')]
      endif
      if idx == -1 && s:PreviousToken() ==# 'switch' && s:IsSwitch()
        let l:switch_offset = &cino !~ ':' ? s:sw() : s:ParseCino(':')
        if pline[-1:] != '.' && l:line =~# '^\%(default\|case\)\>'
          return s:Nat(num_ind + l:switch_offset)
        elseif &cino =~ '='
          let l:case_offset = s:ParseCino('=')
        endif
      endif
    endif
    if idx == -1 && pline[-1:] !~ '[{;]'
      call cursor(l:lnum, len(pline))
      let sol = matchstr(l:line,s:opfirst)
      if sol is '' || sol == '/' && s:SynAt(v:lnum,
            \ 1 + len(getline(v:lnum)) - len(l:line)) =~? 'regex'
        if s:Continues()
          let is_op = s:sw()
        endif
      elseif num && sol =~# '^\%(in\%(stanceof\)\=\|\*\)$' &&
            \ s:LookingAt() == '}' && s:GetPair('{','}','bW',s:skip_expr) &&
            \ s:PreviousToken() == ')' && s:GetPair('(',')','bW',s:skip_expr) &&
            \ (s:PreviousToken() == ']' || s:LookingAt() =~ '\k' &&
            \ s:{s:PreviousToken() == '*' ? 'Previous' : ''}Token() !=# 'function')
        return num_ind + s:sw()
      else
        let is_op = s:sw()
      endif
      call cursor(l:lnum, len(pline))
      let b_l = s:Nat(s:IsContOne(is_op) - (!is_op && l:line =~ '^{')) * s:sw()
    endif
  elseif idx.s:LookingAt().&cino =~ '^-1(.*(' && (search('\m\S','nbW',num) || s:ParseCino('U'))
    let pval = s:ParseCino('(')
    if !pval
      let [Wval, vcol] = [s:ParseCino('W'), virtcol('.')]
      if search('\m\S','W',num)
        return s:ParseCino('w') ? vcol : virtcol('.')-1
      endif
      return Wval ? s:Nat(num_ind + Wval) : vcol
    endif
    return s:Nat(num_ind + pval + searchpair('\m(','','\m)','nbrmW',s:skip_expr,num) * s:sw())
  endif

" main return
  if l:line =~ '^[])}]\|^|}'
    if l:line_raw[0] == ')'
      if s:ParseCino('M')
        return indent(l:lnum)
      elseif num && &cino =~# 'm' && !s:ParseCino('m')
        return virtcol('.') - 1
      endif
    endif
    return num_ind
  elseif num
    return s:Nat(num_ind + get(l:,'case_offset',s:sw()) + l:switch_offset + b_l + is_op)
  endif
  return b_l + is_op
endfunction

let &cpo = s:cpo_save
unlet s:cpo_save

${this.title}

Code Editor : javascript.vim